home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib07.dsk / SCROLLING DEMO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  5KB  |  142 lines
  1. 2  REM  ******************************
  2. 3  REM  *   SCROLLING DEMO           *
  3. 4  REM  *   BY ROBERT A WELLS        *
  4. 5  REM  *   COPYRIGHT (C) 1982       *
  5. 6  REM  *   BY MICRO-SPARC INC       *
  6. 7  REM  *   LINCOLN, MA. 01773       *
  7. 8  REM  ******************************
  8. 10  REM  HELLO WITH SCROLL DEMO
  9. 20  GOSUB 1200
  10. 30  PRINT  CHR$(4);"BLOAD SCROLL SUITE"
  11. 40 SU = 768:SD = 806:SR = 848:SL = 885
  12. 50 WL = 32:WW = 33:WT = 34:WB = 33
  13. 60  HOME 
  14. 70  VTAB 2
  15. 80  PRINT "HELLO THERE!"
  16. 90  FOR I = 1 TO 13: CALL SR: NEXT 
  17. 100  FOR I = 1 TO 11: CALL SD: NEXT 
  18. 110 W = 2000: GOSUB 1190
  19. 120 W = 500
  20. 130  HOME 
  21. 140  VTAB 12: PRINT " A"
  22. 150  GOSUB 1190
  23. 160  FOR I = 1 TO 6: CALL SR: NEXT 
  24. 170  POKE WL,8: POKE WW,32
  25. 180  VTAB 2: HTAB 1: PRINT " SMALL"
  26. 190  GOSUB 1190
  27. 200  FOR I = 1 TO 10: CALL SD: NEXT 
  28. 210  POKE WL,14: POKE WW,26
  29. 220  VTAB 12: HTAB 16: PRINT " SCROLLING"
  30. 230  GOSUB 1190
  31. 240  FOR I = 1 TO 15: CALL SL: NEXT 
  32. 250  POKE WL,24: POKE WW,16
  33. 260  VTAB 23: HTAB 1: PRINT " EXAMPLE"
  34. 270  GOSUB 1190
  35. 280  FOR I = 1 TO 11: CALL SU: NEXT 
  36. 290  POKE WL,0: POKE WW,40
  37. 300 W = 2000: GOSUB 1190
  38. 310  HOME 
  39. 320  POKE  -16302,1: POKE  -16304,1: REM  GO TO FULL SCREEN GRAPHICS
  40. 330  COLOR= 1: PLOT 0,0: PLOT 0,1
  41. 340  FOR I = 1 TO 47: CALL SR: CALL SD: NEXT 
  42. 350  FOR V = 2 TO 5
  43. 360 L =  LEN(L$(V)) -1
  44. 370 B = B(V)
  45. 380  FOR H = 0 TO L
  46. 390  POKE B +H, ASC( MID$ (L$(V),H +1,1))
  47. 400  NEXT 
  48. 410  NEXT 
  49. 420  VTAB 5: PRINT L5$
  50. 430 W = 1000: GOSUB 1190
  51. 440  FOR I = 1 TO 7: CALL SR: NEXT 
  52. 450  FOR I = 1 TO 18: CALL SD: NEXT 
  53. 460  FOR I = 1 TO 7: CALL SL: NEXT 
  54. 470  FOR I = 1 TO 18: CALL SU: NEXT 
  55. 480  FOR I = 1 TO 18: CALL SD: NEXT 
  56. 490  FOR I = 1 TO 3: CALL SR: NEXT 
  57. 500  FOR I = 1 TO 9: CALL SU: NEXT 
  58. 510 W = 500: GOSUB 1190
  59. 520  POKE WW,20
  60. 530  FOR I = 1 TO 3
  61. 540  POKE WL,0: CALL SL
  62. 550  POKE WL,19: CALL SR
  63. 560  NEXT 
  64. 570  GOSUB 1190
  65. 580  FOR I = 1 TO 3
  66. 590  POKE WL,0: CALL SR
  67. 600  POKE WL,19: CALL SL
  68. 610  NEXT 
  69. 620 W = 500: GOSUB 1190
  70. 630  POKE WL,0: POKE WW,40: POKE WT,12: POKE WB,24
  71. 640  FOR I = 1 TO 9: CALL SD: NEXT : GOSUB 1190
  72. 650  FOR I = 1 TO 9: CALL SU: NEXT : GOSUB 1190
  73. 660  POKE WT,0: POKE WB,12
  74. 670  FOR I = 1 TO 9: CALL SU: NEXT : GOSUB 1190
  75. 680  FOR I = 1 TO 9: CALL SD: NEXT : GOSUB 1190
  76. 690  POKE WB,24
  77. 700  POKE WL,0: POKE WB,24
  78. 710  COLOR= 1: HLIN 0,39 AT 22: HLIN 0,39 AT 23
  79. 720  FOR I = 1 TO 20
  80. 730  POKE WW,20: POKE WT,0: CALL SL
  81. 740  POKE WW,40: POKE WB,12: CALL SU
  82. 750  POKE WL,19: POKE WW,21: POKE WB,24: CALL SR
  83. 760  POKE WT,11: POKE WL,0: POKE WW,40: CALL SD
  84. 770  NEXT : GOSUB 1190
  85. 780  POKE WT,0
  86. 790  POKE WL,0: POKE WW,20:J = 0
  87. 800  FOR I = 1 TO 50: COLOR=  RND(1) *16
  88. 810  VLIN 0,47 AT J +19
  89. 820  IF J = 0  THEN  CALL SL
  90. 830  IF J = 1  THEN  CALL SR
  91. 840 J = 1 -J: POKE WL,J *20
  92. 850  NEXT 
  93. 860  POKE WL,0: POKE WW,40: POKE WT,0: POKE WB,12:J = 0
  94. 870  FOR I = 1 TO 50
  95. 880  COLOR=  RND(1) *16
  96. 890  HLIN 0,39 AT J +23
  97. 900  IF J = 0  THEN  CALL SU
  98. 910  IF J = 1  THEN  CALL SD
  99. 920 J = 1 -J: POKE WT,J *12: POKE WB,(J +1) *12
  100. 930  NEXT 
  101. 940  POKE WL,0: POKE WW,20: POKE WT,0: POKE WB,12:J = 0
  102. 950  FOR I = 1 TO 100
  103. 960  COLOR=  RND(1) *16
  104. 970  IF J = 1  THEN 1040
  105. 980  REM  J = 0
  106. 990  VLIN 22,25 AT 19
  107. 1000  COLOR=  RND(1) *16: HLIN 0,39 AT 23
  108. 1010  POKE WL,0: POKE WW,40: POKE WT,0: POKE WB,12: CALL SU
  109. 1020  POKE WW,20: POKE WB,24: CALL SL
  110. 1030  GOTO 1090
  111. 1040  REM  J = 1
  112. 1050  VLIN 22,25 AT 20
  113. 1060  COLOR=  RND(1) *16: HLIN 0,39 AT 24
  114. 1070  POKE WL,0: POKE WW,40: POKE WT,12: POKE WB,24: CALL SD
  115. 1080  POKE WL,20: POKE WW,20: POKE WT,0: CALL SR
  116. 1090 J = 1 -J: NEXT 
  117. 1100  POKE  -16301,1
  118. 1110  POKE WL,0: POKE WW,40: POKE WT,0: POKE WB,24
  119. 1120  VTAB 21: HTAB 1: CALL  -958
  120. 1130  VTAB 23: HTAB 2: INVERSE : PRINT " HIT ANY KEY TO END ": NORMAL 
  121. 1140  GET T$
  122. 1150  COLOR= 0: VLIN 0,39 AT 0
  123. 1160  FOR I = 1 TO 39: CALL SR: NEXT 
  124. 1170  TEXT : HOME 
  125. 1180  END 
  126. 1190  FOR IW = 1 TO W: NEXT : RETURN 
  127. 1200  REM  INITIALIZE
  128. 1210  DIM BB$(2),BM$(4),MB$(2),MM$(5),L$(5),B$(5)
  129. 1220 BB$ =  CHR$(0):BB$(2) = BB$ +BB$
  130. 1230 BM$ =  CHR$(16):BM$(2) = BM$ +BM$
  131. 1240 BM$(3) = BM$(2) +BM$:BM$(4) = BM$(2) +BM$(2)
  132. 1250 MB$ =  CHR$(1):MB$(2) = MB$ +MB$
  133. 1260 MM$ =  CHR$(17):MM$(2) = MM$ +MM$
  134. 1270 MM$(3) = MM$(2) +MM$
  135. 1280 MM$(4) = MM$(2) +MM$(2)
  136. 1290 MM$(5) = MM$(3) +MM$(2)
  137. 1300 L$(2) = MM$(2) +MB$ +BM$(3) +MM$ +MB$ +BM$(2) +MB$ +MM$ +BB$ +BM$(2) +MB$ +MM$ +MB$ +BM$(2) +MB$ +MM$ +BB$ +MM$(4) +BB$
  138. 1310 L$(3) = MM$(2) +BM$ +MB$(2) +MM$(2) +BB$ +MM$(4) +BB$ +MB$(2) +BM$ +MM$ +BB$ +MM$(2) +BB$ +MM$ +BB$ +MM$(4) +BB$
  139. 1320 L$(4) = MM$(5) +BB$ +MM$ +BB$ +MM$(2) +MB$ +MM$ +BB$ +MM$ +BM$ +MB$ +MM$ +BB$ +MM$(2) +BB$ +MM$ +BB$ +MM$(4) +BB$
  140. 1330 L$(5) = MM$(2) +BM$(3) +MM$(3) +BM$(2) +MM$(2) +BM$ +MM$(2) +BM$ +MM$(2) +BM$(2) +MM$(2) +BM$(4) +MM$ +BM$(4)
  141. 1340 B(2) = 1152:B(3) = 1280:B(4) = 1408:B(5) = 1536
  142. 1350  RETURN